BLOCK_LOAD		lfsr		FSR1,0x080			;EEPROM -> RAM
				movlw		.30					;I2C Sequential Read Operation (30 Byte egyhuzamban)
				movwf		I2CCYC				;Olvasandó Byte-ok száma
				call		I2C_START
				movlw		0xA0				;Device Specific Control Byte (Write Command)
				call		I2C_TX				;
				movlw		0x00				;Word Address High Byte
				call		I2C_TX				;
				movlw		0x00				;Word Address Low Byte
				call		I2C_TX				;				
				call		I2C_RESTART
				movlw		0xA1				;Device Specific Control Byte (Read Command)
				call		I2C_TX				;
I2C_BLCYC		decfsz		I2CCYC				;Data Byte Reading Cycle
				bra			I2C_BLCNT			;
				bsf			SSPCON2,ACKDT		;End operations
				call		I2C_DEBUG			;Reg dump to lcd
				call		I2C_STOP			;
				return							;
I2C_BLCNT		bcf			SSPCON2,ACKDT		;Data Byte Reading
				call		I2C_RX
				movff		TEMP2,POSTINC1		;TEMP2-ben az olvasott adat
				bra			I2C_BLCYC
				return
;
I2C_START		bcf			PIR1,SSPIF			;I2C Start Condition
				bsf			SSPCON2,SEN
SSCYC			btfss		PIR1,SSPIF
				bra			SSCYC
				return
;
I2C_RESTART		bcf			PIR1,SSPIF			;I2C Restart Condition
				bsf			SSPCON2,RSEN
RSCYC			btfss		PIR1,SSPIF
				bra			RSCYC
				return
;
I2C_STOP		bcf			PIR1,SSPIF			;I2C Stop Condition
				bsf			SSPCON2,PEN
STCYC			btfss		PIR1,SSPIF
				bra			STCYC
				return		
;
I2C_TX			bcf			PIR1,SSPIF			;I2C Byte Sending Routine (Byte in W)
				movwf		SSPBUF
TXCYC			btfss		PIR1,SSPIF
				bra			TXCYC
;				btfsc		SSPCON2,ACKSTAT		;ACK figyelése, ha szükséges
;				bra			I2C_ACKFAIL
				return
;
I2C_RX			bcf			PIR1,SSPIF			;I2C Byte Reading Routine (Readed Byte in TEMP2)
				bsf			SSPCON2,RCEN
RXCYC			btfss		PIR1,SSPIF
				bra			RXCYC
				movff		SSPBUF,TEMP2 
				bcf			PIR1,SSPIF
				bsf			SSPCON2,ACKEN
RXCYC2			btfss		PIR1,SSPIF			;ACK kiadása
				bra			RXCYC2
				return
;
I2C_POLL		movlw		0xFF				;Maximális várakozási ciklus
				movwf		I2CPOLL
I2C_PCYC		rcall		I2C_RESTART
				movlw		0xA0
				call		I2C_TX
				btfss		SSPCON2,ACKSTAT
				bra			I2C_PEXT
				decfsz		I2CPOLL
				bra			I2C_PCYC
				bra			I2C_TIMEOUT
I2C_PEXT		rcall		I2C_STOP
				return
;