; gépi ciklusok száma
	; zárójelben a mag utolsó végrehajtásakor érvényes ciklusszám
DELAY

	; C1 ciklus kezdete

	MOVLW	d'10'		; 1
	MOVWF	T1		; 1

	; C1 előkészítés: 2 gépi ciklus

DEL

	; C2 ciklus kezdete

	MOVLW	d'10'		; 1
	MOVWF	T2		; 1

	; C2 előkészítés: 2 gépi ciklus

DEL1

	; C3 ciklus kezdete

	MOVLW	d'5'		; 1
	MOVWF	T3		; 1

	; C3 előkészítés: 2 gépi ciklus

DEL2
	NOP			; 1
	DECFSZ	T3,f	; 1 (2)
	GOTO	DEL2		; 2 (0)

	; C3 ciklus vége
	; a mag hossza:
	; 4 gépi ciklus a közbülső iterációkban
	; 3 gépi ciklus az utolsó iterációban

	; C3 mag teljes hosszának számítása:
	; előkészítés ideje: 2 gépi ciklus
	; közbülső iterációkból adódó idő: (T3-1)*4 gépi ciklus
	; utolsó iterációból adódó idő: 3 gépi ciklus
	; C3 ciklus hossza összesen: 2 + (T3-1)*4 + 3 gépi ciklus
	; C3 ciklus hossza összesen egyszerűsítve: (T3-1)*4+5 gépi ciklus

	DECFSZ	T2,f	; 1 (2)
	GOTO	DEL1		; 2 (0)

	; C2 ciklus vége
	; a mag hossza:
	; (C3 összes hossza + 3) gépi ciklus a közbülső iterációkban
	; (C3 összes hossza + 2) gépi ciklus az utolsó iterációban

	; C2 mag teljes hosszának számítása:
	; előkészítés ideje: 2 gépi ciklus
	; közbülső iterációkból adódó idő: (T2-1) * ((T3-1)*4+5 + 3) gépi ciklus
	; utolsó iterációból adódó idő: ((T3-1)*4+5) + 2 gépi ciklus
	; C2 ciklus hossza összesen: (T2-1) * ((T3-1)*4+5 + 3) + ((T3-1)*4+5) + 2 gépi ciklus
	; C2 ciklus hossza összesen egyszerűsítve: T2*((T3-1)*4+8)-1 gépi ciklus

	DECFSZ	T1,f	; 1 (2)
	GOTO	DEL		; 2 (0)

	; C1 ciklus vége
	; a mag hossza:
	; (C2 összes hossza + 3) gépi ciklus a közbülső iterációkban
	; (C2 összes hossza + 2) gépi ciklus az utolsó iterációban

	; C1 mag teljes hosszának számítása:
	; előkészítés ideje: 2 gépi ciklus
	; közbülső iterációkból adódó idő: (T1-1) * (T2*((T3-1)*4+8)-1 + 3) gépi ciklus
	; utolsó iterációból adódó idő: T2*((T3-1)*4+8)-1 + 2 gépi ciklus
	; C1 ciklus hossza összesen: (T1-1) * (T2*((T3-1)*4+8)-1 + 3) + T2*((T3-1)*4+8)-1 + 2 gépi ciklus
	; C1 ciklus hossza összesen: T1*(T2*(T3*4+4)+2)-1 gépi ciklus
	; C1 ciklus hossza összesen egyszerűsítve: T1*(T2*(T3*4+4)+2)-1 gépi ciklus

	RETURN		; 2

; T1=10,T2=10,T3=5 behelyettesítéssel C1 teljes hossza = 2419 gépi ciklus